Skype - World Time

Skype is a software application that allows registered users to communicate with each other through video calls and instant messaging. While making international calls, the caller will always prefer to keep the time difference in mind. This sample demonstrates how Xtend IVR can be used to get the world time via Skype. Utilise this scripting language to screen scrape information from a website.

Download the evaluation version of Xtend IVR and install the telephony application in your system. Run the sample script from the Script Editor. Click here to refer the code.

The automated attendant will work as given below:

• Initially, IVR loads the mapped country code
• IVR waits for the chat message
• On receiving the chat, IVR displays the chat message and removes the unwanted leading and trailing white spaces
• IVR prompts the user to enter the country name with at least 3 characters
• If there is an exact match, then IVR gets the time from the website and append it with the response string
• If there is no exact match, then IVR tries to match the closest word and based on that returns all matching results

Download the source file for the Skype - WorldTime

*******************************************************************************************
* Script  : Time.dt
* Notes   : Returns the current time in the specified country from www.worldtimeserver.com
* Caution : This is only a sample to demonstrate how the scripting language can be 
*          used to screen scrape information from a website. Actual use of this script 
*          will require you to obtain the necessary permission from the website owner.
*******************************************************************************************

* Uncomment the next line to write raw skype command & reponses to the user log file
* $Skype.debug = true

* Load the country code mapping
LoadFile("CountryMap.txt","$CountryMap")


MAIN:
	Display "Waiting for chat . . ."
		
	* Wait till we get a chat message
	while !Skype.GetChatMessage()
		SleepEvent 
	endwhile
		
	* Show the incoming message
	Display  "Received message from " $SkypeChat.FROM_HANDLE " -> " $SkypeChat.
	
	* Upcase the received message
	$Country = $SkypeChat.BODY
	$Country = alltrim($Country)
	
	* Name of Country should be at least 3 chars
	if len($Country) < 3
		Skype.SendChatMessage($SkypeChat.CHATNAME, "Please send me the name of 
			the country for which you require the current time.")
		goto MAIN
	endif
	
	* See if there is an exact match
	$Response = ScanCountryMap($Country)
	if $Response == ""
		* If not exact match, try to match anywhere and return all matching
		$Response = ScanCountryMap($Country, true)
	endif
	
	if $Response == ""
		$Response = Format("I do not know the current time for country %s. 
		It is possible that this country has many time zones. 
		Please try a specific state or city in %s", $Country, $Country)
	endif
	Skype.SendChatMessage($SkypeChat.CHATNAME, $Response)
	goto MAIN


Function ScanCountryMap($Country, $MatchAnywhere)	
	* Scan through all the lines looking for a match anywhere
	* Some country name might match multiple times :-) 
	* for e.g. korea would return the current time in south & north korea
	$LineNumber = 1
	$ResponseStr = ""
	while $LineNumber <= $CountryMap.Filelines
		* Use a variable pointer i.e. $$
		$CurrLine = Format("$CountryMap.Line%d",$LineNumber)
		if Find(Upper($$CurrLine),Upper($Country)) >= 0
			* Ok Found a match so cut out the Country Code
			$pos = Find($$CurrLine," ")
			if $pos >= 0
				* Ok got the Country Code and the 
				Country Name as given in the text file
				$CountryCode = Left($$CurrLine,$pos)
				$CountryName = Mid($$CurrLine,$pos+1)
				
				if !$MatchAnywhere 
					if upper(alltrim($CountryName)) <> 
							upper(alltrim($Country))
						$LineNumber += 1
						continue
					endif
				endif
				
				Display Format("(%s) Looking up time for %s",
							$Country, $CountryName)
				
				* Use this to get the time from the website
				$CurrTime = GetTimeFromWorldTimeServer($CountryCode)
				if $CurrTime == ""
					$LineNumber += 1
					continue
				endif
				
				* Format and appends to the response string
				$Str = Format("The current time in %s is %s", 
							$CountryName, $CurrTime)
				if $ResponseStr = ""
					$ResponseStr = $Str
				else
					$ResponseStr = Format("%s%c%s",$ResponseStr,
								chr(10),$Str)
				endif
			endif
		endif
		$LineNumber += 1
	endwhile
return $ResponseStr


Function GetTimeFromWorldTimeServer($CountryCode)
	* Use http plugin to fetch the webpage
	if http(Format("http://www.worldtimeserver.com/time.asp?
					locationid=%s",$CountryCode)) <> TRUE
		return ""
	endif
	
	 
	; These variables contains text used to locate
	; the time in the returned HTML page
	; These key values may change.
	; Please modify these values if required
	
	$key = '<span class="font7">'
	$endkey = '</span>'
	
	* Locate the time
	$pos = Find($http.Page, $key)
	if $pos < 0
		return ""
	endif
	
	$pos += len($key)
	$CurrTime = Mid($http.Page, $pos)
	
	$pos = Find($CurrTime,$endkey)
	if $pos < 0
		return ""
	endif
	
	* Extract time
	$CurrTime = Mid($CurrTime,0,$pos)
	$pos = find($CurrTime,":")
	if $pos < 0
		return ""
	endif
	
	$hh = mid($CurrTime,0,$pos)
	$pos += 1
	$mm = mid($CurrTime,$pos)
	$pos = find($mm,' ')
	if $pos < 0
		return ""
	endif
	$mm = mid($mm,0,$pos)
	
	$pos = reversefind($CurrTime,' ')
	if $pos < 0
		return ""
	endif
	$ampm = upper(mid($CurrTime, $pos+1, 2))
	
	$Str = Format("%d:%02d %s", $hh,$mm,$ampm)
return $Str


* User has hung up
ONHANGUP:
	hangup
	goto MAIN


* An error has occurred
ONSYSTEMERROR:
	log $error
	display $error
	if $debug 
		msgbox $error
	endif
	hangup
	goto MAIN

*End of Script