Skype - Answering Machine

Deploying automatic answering system using Xtend IVR will ensure that every customer call is answered promptly without any delay andyour business always stay connected even, if you are not available to answer your incoming Skype calls. The automated IVR picks up the incoming call and processes the call at a faster pace while recording and storing all the phone conversations as audio files for future references.

Download the evaluation version of Xtend IVR and install the telephony application in your system. Run the sample script from the Script Editor. Click here to refer the code.

After creating the sample script, you can run the script and it works as follows:

• Initially, set the parameters for IVR configuration and Skype setup
• IVR waits for the call
• Checks whether the connection is established
• If the call appears connected, the phone conversation gets recorded
• If the recipient has not picked up the call within the specified number of rings, then, IVR announces the message
• If call has been picked up within the specified number of rings, IVR stops the answering machine and records the phone conversation

**********************************************************************************
* Script : AM.dt
* Notes  : Implements a Skype Answering Machine / Conversation Recording script
*       : Stores Conversation Recording as CR-YYYYMMDDHHMMSS-DeviceNo.wav 
*       : Stores Answering Machine recordings as AM-YYYYMMDDHHMMSS-DeviceNo.wav 
**********************************************************************************

* Uncomment the next line to write raw skype command & reponses to the user log file
* $Skype.debug = true

* Configuration Settings
$AnsweringMachineRings = 10

* Setup Skype
Skype.Command("SET SILENT_MODE ON")
Skype.Command("MINIMIZE")

	
MAIN:
	voicelog
	display "Waiting for call..."
	Skype.ConnectMMedia(0)
	
WAITFORCALL:
	* Check if call connected (i.e. user picked up)
	$Str = GetCallProgress()
	if $Str == "CONNECTED" then goto CONVERSATIONRECORDING
	
	* If ringing exceeded limit set for answering machine mode
	if $Ring > 0
		display "Incoming call..."
	endif
	if $Ring >= $AnsweringMachineRings then goto ANSWERINGMACHINE
	
	* Get and Discard the Skype responses
	if Skype.Response() == ""
		SleepEvent 100
		goto WAITFORCALL
	endif
	goto WAITFORCALL
	

ANSWERINGMACHINE:
	display "Answering Machine"
	answer 1
	
	$Curr = GetTime()
	$CallWaveFile = Format("AM-%04u%02u%02u%02u%02u%02u-%03u.wav", 
			mid($curr,0,4), mid($curr,5,2), mid($curr,8,2), 
			mid($curr,11,2), mid($curr,14,2), mid($curr,17,2), $DeviceId)
	voiceLog $CallWaveFile
    
	Skype.ConnectMMedia(1)
	speak "Hi I am currently not at home, could you kindly leave a message
					and I'll get back to you."
	play "\pau=500\"
	while PlayTimeLeft() > 0
		* Get and Discard the responses
		if Skype.Response() == ""
			SleepEvent 50
			continue
		endif
		* Stop Answering Machine and goto Conversation Recording
		* if User focuses on contacts
		if Left($Skype.Response,16) == "CONTACTS FOCUSED"
			VoiceLog
			goto CONVERSATIONRECORDING
		endif 
	endwhile
	beep 
	
	record 60
	while RecordTimeLeft() > 0
		* Get and Discard the responses
		if Skype.Response() == ""
			SleepEvent 50
			continue
		endif
		* Stop Answering Machine and goto Conversation Recording
		* if User focuses on contacts
		if Left($Skype.Response,16) == "CONTACTS FOCUSED"
			VoiceLog
			goto CONVERSATIONRECORDING
		endif 
	endwhile
	hangup
	goto MAIN
	
	
CONVERSATIONRECORDING:	
	Skype.ConnectMMedia(2)
	$Curr = GetTime()
	$CallWaveFile = Format("CR-%04u%02u%02u%02u%02u%02u-%03u.wav", mid($curr,0,4), 
				mid($curr,5,2), mid($curr,8,2), mid($curr,11,2), 
				mid($curr,14,2), mid($curr,17,2), $DeviceId)
	voiceLog $CallWaveFile
	
	display "Conversation Recording"
	while true
		if Skype.Response() == ""
			SleepEvent
			continue
		endif
	endwhile
	hangup
	goto MAIN

* User has hung up
ONHANGUP:
	hangup
	goto MAIN

* An error has occurred
ONSYSTEMERROR:
	log $error
	display $error
	if $debug 
		msgbox($error)
	endif
	hangup
	goto MAIN
	
*End of Script