BBC RSS Feed

RSS Feed is a way to check for updates to your favorite websites, without having to visit each site individually. This sample demonstrates how the scripting languages can be used to screen scrape information from a website. The automated IVR is introduced to fetch the RSS feed, and play back the information to the caller.

Download the evaluation version of Xtend IVR and install the telephony application in your system. Run the sample script from the Script Editor. Click here to refer the code.

The automated attendant will work as given below:

• IVR waits for the call
• Caller dials the number, IVR accepts the call and plays the Welcome message
• IVR plays the title of the RSS feed
• IVR speaks out the title and description of all the items present in the feed

Download the source file for the Internet Application - BBC RSS Feed

					

******************************************************************************************
* Script  : PlayRSS.dt
* Date    : 19 April 2006
* Notes   : Script that play the specified RSS feed over IVR using Text to Speech
*          Database routines to lookup RSS feed based on Caller Id / PIN Is not added
* Caution : This is only a sample to demonstrate how the scripting language can be 
*          used to screen scrape information from a website. Actual use of this script 
*          will require you to obtain the necessary permission from the website owner.
******************************************************************************************

MAIN:
	answer
	$RSSFeed = "http://newsrss.bbc.co.uk/rss/newsonline_uk_edition/front_page/rss.xml"
	
SPEAK_FEED:
	speak "Welcome to R. S. S. feed reader."
	speak "please wait while we fetch your R. S. S. Feed."
	wait 0
	play "music.wav"
	play "music.wav"
	play "music.wav"
	play "music.wav"
	$Status = GetRss($RSSFeed)
	clear
	
	if $Status == 0
		speak "Unable to fetch the R. S. S. feed you have specified"
		goto BYE
	endif
	
	// Play the title of the feed
	if len($RSS.Title) > 0
		FlashBox("TOPRIGHT",concat(chr(10),"The title of the R. S. S.
					 Feed is ", $RSS.Title,chr(10)))
		speak "The title of the R. S. S. Feed is " $RSS.Title
	else
		speak "The R S S feed does not have a title"
	endif
	
	speak "Total number of items in this feed is" $RSS.ItemCount
	wait 0
	
	// Now speak the Title and Description of all items present in this feed
	$Count = 1
	
	while $Count <= $RSS.ItemCount
		// Pause for 500ms
		play "silence.wav"
		speak "Item " $count
		
		// Pause for 100ms
		play "silence.wav"   
		$Heading = concat("$RSS.", $Count, ".Title")
		$Heading = $$Heading
		FlashBox("TOPRIGHT",concat(chr(10),$Heading,chr(10)))
		speak $Heading 
		wait 0
		
		// Pause for 250ms
		play "silence.wav"   
		$Description = concat("$RSS.", $Count, ".Description")
		$Description = $$Description
		FlashBox("TOPRIGHT",concat(chr(10),$Description,chr(10)))
		speak $Description 
		wait 0
		
		$Count += 1
	endwhile

BYE:
	speak "Thank you for calling Feeds Cast Dot Com"
	FlashBox()
	hangup
	goto MAIN

// User has hung up
ONHANGUP:
	FlashBox()
	hangup
	goto MAIN

* An error has occurred
ONSYSTEMERROR:
	log $error
	display $error
	//speak "We are facing technical problems, please call back after some time"
	hangup
	goto MAIN
					
*End of Script