Exam Results Announcement

When an examination result is released, almost all the official phone numbers in the educational institutes get flocked with enquiries. Under such situations, handling calls get tough due to less number of staffs to answer the incoming calls. To simplify the process, Xtend IVR brings you the most efficient mode of automated services.

Download the evaluation version of Xtend IVR and install the telephony application in your system. Run the sample script from the Script Editor. Click here to refer the code.

The automated attendant will work as given below:

• IVR waits for the call
• Caller dials the number, IVR accepts the call and plays the Welcome message
• IVR prompts the user to enter the register number
• If the register number is valid, IVR informs the marks of each subject
• If the register number is invalid, IVR informs the caller that the entered register number is not correct

Download the source file for the Exam Results Announcement

*******************************************************************
* Script : Result.dt
* Notes : welcomes the caller
*        accepts the roll number of the student
*        query the database to get the rank using VBScript
*        speaks out the marks of Physics, Chemistry, Mathematics
*******************************************************************

MAIN:
	$displayprefix = ""
	display "Waiting for call..."
	
	answer 1
	
	if not $debug
		// When running standard edition show caller id for each display
		if len($cli) <> 0
			$displayprefix = concat("[",$cli,"] ")
		endif
	endif
		
	; All wave files are taken from folder "Waves"
	$wavdir = "Waves"
	
	display "Call in progress.."
	play "welcome.wav"
	
	$retry = 0
	$maxtry = 3
	
GET_ROLLNO:
	if $retry > $maxtry then goto BYE
	
	display "Waiting for Roll Number..."
	play "EntRollNum.wav"
	$RollNo = input(5,3)
	
	$retry += 1
	if len($RollNo) = 0 then goto GET_ROLLNO
	
	// set a 300ms delay in digit2wav and num2wav plugins
	$wavepause = 300
	// speakout the rollnumber entered
	play "RollNumIs.wav"
	play digit2Wav($RollNo, "Sre", "English", 0, 200)
	
	// Calling VBScript function "GetRank" from VBS file "ExamResult.vbs"
	display "Fetching rank..."
	$RCount = ExamResult.GetRank($RollNo)
	
	// Speakout the results
	display "Announcing Results."
	if $RCount = -1
		play "TechProblem.wav"
		goto BYE
	endif
	
	if $RCount = 0
		play "InvldRollNum.wav"
		goto BYE
	endif
	
	if $result.Physics > 0
		play "Physics.wav" 
		play num2wav($result.Physics)
	endif
	if $result.Chemistry > 0
		play "Chemistry.wav" 
		play num2wav($result.Chemistry)
	endif
	if $result.Mathematics > 0
		play "Mathematics.wav" 
		play num2wav($result.Mathematics)
	endif
	
BYE:
	play "ThankU.wav"
	hangup
	goto MAIN

* User has hung up
ONHANGUP:
	hangup
	goto MAIN


* An error has occurred
ONSYSTEMERROR:
	play "TechProblem.wav"
	log $error
	display $error
	hangup
	goto MAIN

*End of Script